Batch Datei als Admin öffnen und den Dateistandort der Datei finden?

Simpel...
Füg das hier relativ zu Beginn der Batch ein:

Code:

cd /d "%~dp0"

Damit wechselst du in das Verzeichnis, wo die gerade gestartete Batch liegt.

Alternativ pack deine Befehle in meine Batch ein. Die macht das ebenfalls automatisch.
Du kannst sie mit Doppelklick starten, dann fragt sie Adminrechte ab.
Du kannst sie auch mit Rechtsklick starten, dann läuft sie ja eh mit Adminrechten.
Kopiere den Inhalt deiner Batch einfach in meine rein.
Benutze dafür bitte die Abschnitte :START_ADMIN oder :START_USER.



Hier meine Batch:

Code:

@echo off

:CHECK
set "all_proxy="
cd /d "%~dp0"
REM In der folgenden Zeile kann das "REM" entfernt werden, damit die Batch auch in Verzeichnissen arbeitet, die Leerzeichen enthalten. Fehlerfreie Funktion kann dann aber nicht garantiert werden.
REM goto START
if NOT "%cd%"=="%cd: =%" (
    echo Der Pfad dieser Batchdatei enth„lt Leerzeichen.
    echo Bitte verschieben Sie diese Skript in ein anderes Verzeichnis OHNE Leerzeichen.
    echo.
    pause
    goto EOF
)

:START
if "[%1]" == "[49127c4b-02dc-482e-ac4f-ec4d659b7547]" goto SUCCESS
REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1 && goto SUCCESS
set command="""%~f0""" 49127c4b-02dc-482e-ac4f-ec4d659b7547
SETLOCAL ENABLEDELAYEDEXPANSION
set "command=!command:'=''!"

powershell -NoProfile Start-Process -FilePath '%COMSPEC%' ^
-ArgumentList '/c """!command!"""' -Verb RunAs 2>NUL
IF %ERRORLEVEL% GTR 0 (
      echo =====================================================
      echo Administratorrechte nicht erteilt.
      echo Skript wird normalen Benutzerrechten fortgesetzt.
      echo =====================================================
      echo.
      cd /d "%~dp0"
      goto START_USER
)
SETLOCAL DISABLEDELAYEDEXPANSION
goto EOF

:SUCCESS
echo =====================================================
echo Administratorrechte erfolgreich erteilt.
echo Skript wird mit Administratorrechten fortgesetzt.
echo =====================================================
echo.
cd /d "%~dp0"
goto START_ADMIN

:START_USER
REM Ab hier beginnen Aufgaben, die mit normalen Benutzerrechten ablaufen k”nnen. Der letzte Befehl muss dennoch "goto EOF" bleiben, alternativ fgen sie einen "exit" Befehl in ihr Skript ein.
REM Der folgende PAUSE-Befehl kann entfernt werden, es gibt dann aber wom”glich keine Information ber die erteilten oder nichterteilten Rechte.
pause
goto EOF

:START_ADMIN
REM Ab hier beginnen Aufgaben, die mit normalen Benutzerrechten ablaufen k”nnen. Der letzte Befehl muss dennoch "goto EOF" bleiben, alternativ fgen sie einen "exit" Befehl in ihr Skript ein.
REM Der folgende PAUSE-Befehl kann entfernt werden, es gibt dann aber wom”glich keine Information ber die erteilten oder nichterteilten Rechte.
pause
goto EOF

:EOF
REM Hier bitte keine Befehle eintragen.
exit

 

Sorry, in meiner ersten Antwort sind Sonderzeichen in der Batch.
Der Editor muss ASCII unterstützen. Codepage 850.
Hier ist der korrigierte Code.

Simpel...
Füg das hier relativ zu Beginn der Batch ein:

Code:

cd /d "%~dp0"

Damit wechselst du in das Verzeichnis, wo die gerade gestartete Batch liegt.

Alternativ pack deine Befehle in meine Batch ein. Die macht das ebenfalls automatisch.
Du kannst sie mit Doppelklick starten, dann fragt sie Adminrechte ab.
Du kannst sie auch mit Rechtsklick starten, dann läuft sie ja eh mit Adminrechten.
Kopiere den Inhalt deiner Batch einfach in meine rein.
Benutze dafür bitte die Abschnitte :START_ADMIN oder :START_USER.



Hier meine Batch:

Code:

@echo off

:CHECK
set "all_proxy="
cd /d "%~dp0"
REM In der folgenden Zeile kann das "REM" entfernt werden, damit die Batch auch in Verzeichnissen arbeitet, die Leerzeichen enthalten. Fehlerfreie Funktion kann dann aber nicht garantiert werden.
REM goto START
if NOT "%cd%"=="%cd: =%" (
    echo Der Pfad dieser Batchdatei enthält Leerzeichen.
    echo Bitte verschieben Sie diese Skript in ein anderes Verzeichnis OHNE Leerzeichen.
    echo.
    pause
    goto EOF
)

:START
if "[%1]" == "[49127c4b-02dc-482e-ac4f-ec4d659b7547]" goto SUCCESS
REG QUERY HKU\S-1-5-19\Environment >NUL 2>&1 && goto SUCCESS
set command="""%~f0""" 49127c4b-02dc-482e-ac4f-ec4d659b7547
SETLOCAL ENABLEDELAYEDEXPANSION
set "command=!command:'=''!"

powershell -NoProfile Start-Process -FilePath '%COMSPEC%' ^
-ArgumentList '/c """!command!"""' -Verb RunAs 2>NUL
IF %ERRORLEVEL% GTR 0 (
      echo =====================================================
      echo Administratorrechte nicht erteilt.
      echo Skript wird normalen Benutzerrechten fortgesetzt.
      echo =====================================================
      echo.
      cd /d "%~dp0"
      goto START_USER
)
SETLOCAL DISABLEDELAYEDEXPANSION
goto EOF

:SUCCESS
echo =====================================================
echo Administratorrechte erfolgreich erteilt.
echo Skript wird mit Administratorrechten fortgesetzt.
echo =====================================================
echo.
cd /d "%~dp0"
goto START_ADMIN

:START_USER
REM Ab hier beginnen Aufgaben, die mit normalen Benutzerrechten ablaufen können. Der letzte Befehl muss dennoch "goto EOF" bleiben, alternativ fügen sie einen "exit" Befehl in ihr Skript ein.
REM Der folgende PAUSE-Befehl kann entfernt werden, es gibt dann aber womöglich keine Information über die erteilten oder nichterteilten Rechte.
pause
goto EOF

:START_ADMIN
REM Ab hier beginnen Aufgaben, die mit normalen Benutzerrechten ablaufen können. Der letzte Befehl muss dennoch "goto EOF" bleiben, alternativ fügen sie einen "exit" Befehl in ihr Skript ein.
REM Der folgende PAUSE-Befehl kann entfernt werden, es gibt dann aber womöglich keine Information über die erteilten oder nichterteilten Rechte.
pause
goto EOF

:EOF
REM Hier bitte keine Befehle eintragen.
exit