Dateiverknüpfungen finden

Um eine doppelte MP3 zu finden, kann man sich einfacher Werkzeuge bedienen, z.B AllDup.

Code:

https://www.giga.de/?docId=01D6BASP63PN6YJ8X9373QVP6V&dlId=6042

 

Hallo,

kopiere folgenden Code in eine Textdatei:

Code:

Const FOLDER_PATH = "G:\Eigene Dateien" 'Anpassen !!!

Dim vntFileSystemObject
Dim vntShellObject
Dim vntTextfile
Dim vntMainFolder

Set vntFileSystemObject = CreateObject("Scripting.FileSystemObject")
Set vntShellObject = CreateObject("Shell.Application")

Set vntTextfile = vntFileSystemObject.CreateTextFile(FOLDER_PATH & "\Verknuepfungen.txt", True)

Set vntMainFolder = vntFileSystemObject.GetFolder(FOLDER_PATH)

Call Main(vntMainFolder, vntShellObject, vntFileSystemObject, vntTextfile)

Call vntTextfile.Close

Set vntTextfile = Nothing
Set vntMainFolder = Nothing
Set vntFileSystemObject = Nothing
Set vntShellObject = Nothing

Call MsgBox("Fertig", vbInformation, "Info")

Private Sub Main(vntRootDir, vntShellObject, vntFileSystemObject, vntTextfile)

    Dim vntFolderObject
    Dim vntFileObject
    Dim vntLinkObject
    Dim vntSubFolderObject

    Set vntFolderObject = vntShellObject.Namespace(vntRootDir.Path)

    For Each vntFileObject In vntFolderObject.Items

        If vntFileObject.IsLink Then

            Set vntLinkObject = vntFileObject.GetLink

            With vntLinkObject

                If .Path <> vbNullString Then

                    If Not .Target.IsBrowsable Then

                        Call vntTextfile.WriteLine(vntRootDir.Path & vbTab & .Path)

                    End If
                End If
            End With
        End If
    Next

    For Each vntSubFolderObject In vntRootDir.SubFolders

        Call Main(vntSubFolderObject, vntShellObject, vntFileSystemObject, vntTextfile)

    Next

    Set vntFolderObject = Nothing
    Set vntFileObject = Nothing
    Set vntLinkObject = Nothing
    Set vntSubFolderObject = Nothing

End Sub

Passe den Ordner hier:

Const FOLDER_PATH = "G:\Eigene Dateien" 'Anpassen !!!

an. Speichere die Datei. Ändere die Endung von .txt zu .vbs und starte das Programm mit einem Doppelklick. Es legt dir in dem Ordner eine Textdatei mit dem Namen "Verknuepfungen.txt" an in der sich alle Verknüpfungen befinden bzw. den Ordner und zu welcher Datei / welchem Ordner sie führt. Am Ende kommt eine Messagebox mit "Fertig !"